home *** CD-ROM | disk | FTP | other *** search
/ Aminet 1 / Aminet - June 1993 [Walnut Creek].iso / usenet / sources / volume2 / libraris / remlib.1 < prev   
Encoding:
Internet Message Format  |  1988-11-18  |  23.0 KB
  1. Path: xanth!mcnc!rutgers!mit-eddie!ll-xn!adelie!infinet!ulowell!page
  2. From: page@swan.ulowell.edu (Bob Page)
  3. Newsgroups: comp.sources.amiga
  4. Subject: v02i064:  remlib - remove a library from memory v1.11
  5. Message-ID: <10261@swan.ulowell.edu>
  6. Date: 18 Nov 88 04:42:14 GMT
  7. Organization: University of Lowell, Computer Science Dept.
  8. Lines: 789
  9. Approved: page@swan.ulowell.edu
  10.  
  11. Submitted-by: schabacker@frambo.DEC.COM (Tim, posting for Christian Balzer)
  12. Posting-number: Volume 2, Issue 64
  13. Archive-name: libraries/remlib.1
  14.  
  15. RemLib is an update to the one on Fish #139.
  16. If there are any questions, email me.
  17.  
  18. [uuencoded binary also here, because it's small and the
  19. redistribution requirements state that it must be.  ..Bob]
  20.  
  21. #    This is a shell archive.
  22. #    Remove everything above and including the cut line.
  23. #    Then run the rest of the file through sh.
  24. #----cut here-----cut here-----cut here-----cut here----#
  25. #!/bin/sh
  26. # shar:    Shell Archiver
  27. #    Run the following text with /bin/sh to create:
  28. #    remlib.asm
  29. #    remlib.uu
  30. # This archive created: Thu Nov 17 23:28:05 1988
  31. cat << \SHAR_EOF > remlib.asm
  32. *****************************************************************************
  33. *
  34. * RemLib.asm    by    HEIKO RATH 
  35. *            copyright 1987/88 by the Software Brewery
  36. *
  37. * The purpose of this program is to remove a library from the librarylist.
  38. * To be save, it only removes librarys with an OpenCnt of 0.
  39. * To get a list of all librarys use RemLib without an argument.
  40. *                                Heiko Rath
  41. * Version 1.00 - printed all libraries with one Write (with many libs -> GURU)
  42. * Version 1.01 - prints every row with an extra Write
  43. * Version 1.05 - now features positive and negative size of library
  44. * Version 1.10 - now stops on CTRL-C
  45. * Version 1.11 - worked on error texts
  46. *
  47. *
  48. * This program is
  49. *  
  50. * Copyright (c) 1988 by Heiko Rath and the Software Brewery.
  51. * 
  52. * It may be freely distributed for non-profit only.
  53. * The distribution must contain ALL parts, in this case the following
  54. * files:
  55. * 
  56. * RemLib
  57. * RemLib.asm
  58. * 
  59. * Putting it on a commercial product is usually as easy as sending
  60. * a letter to the author.
  61. *
  62. *****************************************************************************
  63. *______  /          
  64. *______\O                     - The Software Brewery - 
  65. *      \\ 
  66. *       o           Sparkling, fresh software from West-Germany
  67. *
  68. *     @@@@@             Straight from the bar to your Amiga
  69. *     |~~~|\ 
  70. *     | | |/ 
  71. *     |___|        With our regards to the Software Distillery
  72. *
  73. *Christian Balzer alias <CB>, Lattice C, user interfaces, beer addict. 
  74. *Heiko Rath alias <HR>, Assembler, ROM-Kernal stuff, Marabou & beer addict. 
  75. *Ralf Woitinas alias RAF, Assembler, anything, Ray-Tracing addict.
  76. *Andrew Kopp alias Charlie, Aztec C, Hardware & communications, beer addict.
  77. *Armin Sparr alias MARVIN, Aztec C, ARexx macros, Campari addict.
  78. *Christof Bonnkirch alias KEY, Aztec C, Hardware & Devices, beer addict.
  79. *
  80. *Beverages: Altenmuenster Brauer Bier, Urfraenkisches Landbier, Jever.
  81. *
  82. *Send exotic drinks, mail, comments and flames to:
  83. *
  84. *The Software Brewery
  85. *Christian Balzer        UUCP: decwrl!frambo.dec.com!schabacker
  86. *Im Wingertsberg 45        ARPA: schabacker@frambo.dec.com
  87. *D-6108 Weiterstadt        CIS : 71001,210 (be brief!)
  88. *WEST GERMANY (F.R.G.)        Fone: +49 6150 4151 (18:00-21:00 CET!)
  89. *
  90. *
  91. *Send the above stuff, beautiful girls and of course MARABOU-CHOCOLATE to:
  92. *
  93. *Heiko Rath (HHHEEELLLPPP, I'm running out of MARABOU chocolate!!!!!!!)
  94. *Raiffeisenstr.10a
  95. *D-6108 Weiterstadt
  96. *WEST GERMANY (F.R.G.)
  97. *
  98.  
  99. Version        MACRO
  100.         dc.b    '1.11'
  101.         ENDM
  102.  
  103. ExecBase    Equ    4
  104.  
  105. ***
  106. *** Exec Offsets:
  107. ***
  108. OpenLibrary    Equ    -552        ;OpenLibrary (LibName,version)(a1,d0)
  109. CloseLibrary    Equ    -414        ;CloseLibrary (Library)(a1)
  110. Forbid        Equ    -132        ;Forbid ()()
  111. Permit        Equ    -138        ;Permit ()()
  112. AllocMem    Equ    -198        ;AllocMem (bytesize,requirement)(d0,d1)
  113. FreeMem        Equ    -210        ;FreeMem (memoryblock,bytesize)(a1,d0)
  114. FindName    Equ    -276        ;FindName (list,name) (a0,a1)
  115. RemLibrary    Equ    -402        ;RemLibrary (library)(a1)
  116. SetSignal    Equ    -306        ;SetSignal (newSignals,signalMask)(d0,d1)
  117.  
  118. ***
  119. *** DOS Offsets:
  120. ***
  121. OutPut        Equ    -60        ;OutPut ()
  122. Input        Equ    -54        ;Input ()
  123. Write        Equ    -48        ;Write (file,buffer,length)(d1,d2,d3)
  124.  
  125. ***
  126. *** I use these Macros to make things easier for me
  127. ***
  128.  
  129. doit:    MACRO
  130.     move.l    #HeadLine,d2        ;address of HeadLine to d2
  131.     bsr    TextOutPut        ;output HeadLine
  132.     move.l    \1,d0            ;offset of listhead to d0
  133.     bsr    Showlib            ;output library-list
  134.     ENDM
  135.  
  136. ***
  137. *** Here we go:
  138. ***
  139.     move.l    sp,d6            ;store stack pointer on stack
  140.     move.l    a0,a2            ;save cmdline address
  141.     sub.w    #1,d0
  142.     clr.b    0(a2,d0.w)        ;make the cmdline null terminated
  143.  
  144.     move.l    ExecBase,a6        ;Execaddress to a6 (only to be sure)
  145.     move.l    #DOSNAME,a1        ;Librarynamepointer to a1
  146.     moveq    #0,d0            ;any version
  147.     jsr    OpenLibrary(a6)        ;try to open DOS-Libary
  148.     tst.l    d0            ;is d0 = NULL?
  149.     beq    ErrorExit        ;exit if call wasn't successfull
  150.     move.l    d0,DOSBase        ;save DOSBasepointer
  151.     move.l    d0,a6            ;move DOSBasepointer to a6
  152.     jsr    OutPut(a6)        ;identify the initial output handle
  153.     move.l    d0,stdout        ;save stdout
  154.  
  155.     move.l    #Text,d2
  156.     bsr    TextOutPut
  157.  
  158. SkipSP:    
  159.     move.b    (a2)+,d1        ;skip spaces
  160.     beq    ShowTheLibs        ;if NULL-String then /* show librarys */
  161.     cmp.b    #' ',d1            ;is it a Space ?
  162.     beq.b    SkipSP            ;yes -> SkipSP
  163.  
  164.     cmp.b    #'?',d1            ;is it '?' ?
  165.     beq    ShowHow            ;yes -> ShowHow
  166.  
  167.     cmp.b    #'"',d1            ;is it '"' ?
  168.     bne.b    001$            ;yes -> 001$
  169.     add.l    #1,a2
  170.     move.l    a2,a1
  171. 002$:
  172.     move.b    (a1)+,d1
  173.     beq    NoSuchLibrary
  174.     cmp.b    #'"',d1
  175.     beq.b    003$
  176.     bra.b    002$
  177. 003$:
  178.     sub.l    #1,a1
  179.     move.b    #0,(a1)
  180. 001$:
  181.     sub.l    #1,a2            ;decrement address by one
  182.     move.l    ExecBase,a6        ;ExecBase to a6
  183.     move.l    a6,a0            ;ExecBase to a0
  184.     add.l    liblist,a0        ;address of librarylist to a0
  185.     move.l    a2,a1            ;address of string to a1
  186.     jsr    FindName(a6)        ;search for the given name
  187.     tst.l    d0            ;is there a library with the given name
  188.  
  189.     beq.b    NoSuchLibrary        ;no -> NoSuchLibrary
  190.  
  191.     move.l    d0,a1            ;copy address of library to a1
  192.     move.w    32(a1),d0        ;get OpenCnt
  193.     tst.w    d0            ;is the OpenCnt = 0?
  194.     bne.b    NotZero            ;no -> say that the library is still open
  195.     jsr    RemLibrary(a6)        ;try to close the library
  196.     tst.l    d0
  197.     bne.b    Success            ;->Success
  198.  
  199.     move.l    #FailedToRemove,d2
  200.     bsr    TextOutPut
  201.     bra.b    CloseDOS
  202.  
  203. Success:
  204.     move.l    #Successfull,d2
  205.     bsr    TextOutPut
  206.     bra.b    CloseDOS
  207.  
  208. NoSuchLibrary:
  209.     move.l    #NotFound,d2
  210.     bsr    TextOutPut
  211.     bra.b    CloseDOS
  212.  
  213. NotZero:
  214.     move.l    #NotAbleToClose,d2
  215.     bsr    TextOutPut
  216.     bra.b    CloseDOS
  217.  
  218. ShowTheLibs:
  219.     doit    liblist            ;output Librarylist
  220.  
  221. CloseDOS:
  222.     move.l    ExecBase,a6        ;ExecBase to a6
  223.     move.l    DOSBase,a1        ;DOS-pointer to a1
  224.     move.l    ExecBase,a6        ;Exec-pointer to a6
  225.     jsr    CloseLibrary(a6)    ;close DOS
  226. ErrorExit:
  227.     move.l    d6,sp            ;restore stack pointer
  228.     rts                ;CLI here we go again!!!!
  229.  
  230. ShowHow:
  231.     move.l    #HelpText,d2
  232.     bsr    TextOutPut
  233.     bra.b    CloseDOS
  234.  
  235. *****************************************************************************
  236. *
  237. *    Showlib II                11.1.87 modified on 18.10.88
  238. *            by    Heiko Rath
  239. *                Raiffeisenstr.10a
  240. *                D-6108 Weiterstadt
  241. *                WEST GERMANY (F.R.G.)
  242. *
  243. *
  244. * PURPOSE:            print out Librarylist (address of Node,
  245. *                type, priority, name of Node, version, revision,
  246. *                opencount, negative size, positive size)
  247. *
  248. * ROUTINETYPE:            subroutine
  249. *
  250. * SYNTAX:            bsr Showlib    (Exec-offset to librarylist)(d0)
  251. *
  252. * ENTRY CONDITIONS:        needs DOSlibrary opened and stdout defined
  253. *                also needs DOS-'Write' offset -48 defined.
  254. *                It also needs binhex subroutine.
  255. *
  256. * RETURNS:            none
  257. *
  258. * BUGS:                none
  259. *
  260. * NOTE:                none
  261. *
  262. * CHANGED:            nothing
  263. *
  264. * USAGE:            move.l    LibraryListOffset,d0
  265. *                bsr    Showlib
  266. *
  267. *****************************************************************************
  268. Showlib:
  269.     movem.l    d0-d7/a0-a6,-(sp)    ;save registers
  270.  
  271.     move.l    ExecBase,a6        ;ExecBase to a6
  272.     jsr    Forbid(a6)        ;forbid taskswitching (very important,
  273.                     ; 'cause we are accessing Systemdata)
  274.  
  275.     move.l    a6,a0            ;Execpointer to a0
  276.     add.l    d0,a0            ; + librarylistoffset=address of listhead
  277.     move.l    a0,ListHead        ;save address of listheader -=> ListHead
  278.     move.l    (a0),a1            ;get address of 1.Node to a1
  279.     move.l    a1,Node            ;save address of 1.Node -=> Node
  280.     addq.l    #4,a0
  281.     cmp.l    a1,a0            ;list empty?
  282.                     ;(test if listhead points to listhead+4)
  283.     beq    PrintLF            ;yes -=> send LF and exit
  284.  
  285.     moveq.l    #1,d1            ;set counter to 1 'cause there is at least
  286.                     ; one node in the list
  287. MyCountLoop:
  288.     move.l    (a1),a1            ;get address of next node to a1
  289.     tst.l    (a1)            ;see if contents of (a1) is NULL
  290.     beq.b    EndCount        ;leave counting loop
  291.     addq.l    #1,d1            ;increment counter by one
  292.     bra.b    MyCountLoop        ;do this once more
  293.  
  294. EndCount:
  295.     move.l    d1,NodeCount        ;save number of Nodes
  296.  
  297.     move.l    #71,d0            ;number of bytes per node
  298.     mulu    d1,d0            ;bytes per node * NodeCount
  299.     addq.l    #1,d0            ;add one for the bufferterminating Null
  300.     move.l    d0,MyMemoryLength    ;save lenght of Memoryblock
  301.     move.l    #$10001,d1        ;requirements:MEMF_Public & Clear
  302.     jsr    AllocMem(a6)        ;get memory from system
  303.     move.l    d0,MyMemoryBlock    ;save address of Memoryblock
  304.     move.l    d0,MyMemoryOffset    ;save address of Memoryblock 2.time
  305.     tst.l    d0            ;see if call was successfull
  306.     bne    MoveNodeToBuffer    ;yes -=> MoveNodeToBuffer
  307.  
  308.     move.l    #Err,d2            ;this code is only here, to inform the
  309.     bsr    TextOutPut        ; user that the AllocMem call wasn't
  310.     bra    PrintLF            ; successfull
  311.  
  312. MoveNodeToBuffer:
  313.     move.l    d0,a0            ;get address of MemoryBlock to a0
  314.     move.l    MyMemoryLength,d1    ;get length to d1
  315.  
  316. fill:
  317.     move.b    #' ',(a0)+        ;fill MyMemoryBlock with spaces
  318.     dbeq.b    d1,fill            ;is d1=NULL? (no-=>d1=d1-1-=>fill)
  319.  
  320. TheLoop:
  321.     move.l    MyMemoryOffset,a0    ;get address of MyMemoryOffset to a0
  322.     move.l    Node,a1            ;get address of current node to a1
  323.  
  324.     add.l    #10,a1            ;address of namepointer to a1
  325.     move.l    (a1),a1            ;get address of nodename to a1
  326.     moveq.l    #0,d1            ;this is faster than clr.l d1
  327.     moveq.l    #0,d2            ;set this to NULL for strlen
  328.  
  329. strlen:
  330.     cmp.b    (a1)+,d2        ;NULL?
  331.     beq.b    strlentest        ;yes -=>strlentest
  332.     addq.l    #1,d1            ;increment d1 by one (stringlength)
  333.     bra.b    strlen            ;do the loop once more
  334.  
  335. strlentest:
  336.     cmp.b    #20,d1            ;see if string is greater #20
  337.     ble.b    DoCopy            ;no (less or equal)-=>DoCopy
  338.     move.l    #20,d1            ;set max.length to 20
  339.  
  340. DoCopy:
  341.     move.l    Node,a1            ;get address of node to a1
  342.     add.l    #10,a1            ;address of namepointer to a1
  343.     move.l    (a1),a1            ;get address of nodename to a1
  344.     tst.l    d1            ;see if d1=0
  345.     bne    DoTheCopy        ;jump only if d1<>0
  346.     move.l    #NoName,a1        ;get address of NoName to a1
  347.     moveq.l    #7,d1            ;set length to 7 (length of 'No Name')
  348.  
  349. DoTheCopy:
  350.     subq.l    #1,d1            ;decrement d1 by 1
  351.  
  352. CopyLoop:
  353.     move.b    0(a1,d1),0(a0,d1)    ;copy source to destination
  354.     dbf    d1,CopyLoop        ;decrement d1, if d1<0 then out of loop
  355.  
  356.     move.l    MyMemoryOffset,a0    ;get address of MyMemoryOffset to a0
  357.     move.b    #'$',21(a0)        ;store '$'
  358.     move.b    #'$',35(a0)        ;store '$'
  359.     move.b    #10,69(a0)        ;store LF
  360.     move.b    #0,70(a0)        ;store end of string
  361.  
  362.     move.l    Node,a1            ;get Nodeaddress to a1
  363.     addq.l    #8,a1            ;add 8 to get address of Type
  364.     moveq.l    #0,d0            ;clear d0
  365.     move.b    (a1),d0            ;get Type to d0
  366.     move.l    MyMemoryOffset,a0
  367.     add.l    #31,a0
  368.     bsr    bindecb            ;convert to ASCII
  369.  
  370.     move.l    Node,a1            ;get Nodeaddress to a1
  371.     add.l    #9,a1            ;add 1 to get address of Priority
  372.     moveq.l    #0,d0
  373.     move.b    (a1),d0
  374.     move.l    MyMemoryOffset,a0
  375.     add.l    #35,a0
  376.     bsr    bindecb
  377.  
  378.     move.l    Node,a1            ;get Nodeaddress to a1
  379.     add.l    #32,a1            ;add 32 to get address of OpenCnt
  380.     moveq.l    #0,d0            ;clear d0
  381.     move.w    (a1),d0            ;get OpenCnt to d0
  382.     move.l    MyMemoryOffset,a0
  383.     add.l    #39,a0
  384.     bsr    bindecw            ;convert OpenCnt to ASCII
  385.  
  386.     move.l    Node,a1            ;get Nodeaddress to a1
  387.     add.l    #20,a1
  388.     moveq.l    #0,d0
  389.     move.w    (a1),d0            ;Version
  390.     move.l    MyMemoryOffset,a0
  391.     add.l    #45,a0
  392.     bsr    bindecw
  393.  
  394.     move.l    Node,a1
  395.     add.l    #22,a1
  396.     moveq.l    #0,d0
  397.     move.w    (a1),d0            ;Revision
  398.     move.l    MyMemoryOffset,a0
  399.     add.l    #51,a0
  400.     bsr    bindecw
  401.  
  402.     move.l    Node,a1
  403.     add.l    #16,a1
  404.     moveq.l    #0,d0
  405.     move.w    (a1),d0            ;NegSize
  406.     move.l    MyMemoryOffset,a0
  407.     add.l    #57,a0
  408.     bsr    bindecw
  409.  
  410.     move.l    Node,a1
  411.     add.l    #18,a1
  412.     moveq.l    #0,d0
  413.     move.w    (a1),d0            ;PosSize
  414.     move.l    MyMemoryOffset,a0
  415.     add.l    #63,a0
  416.     bsr    bindecw
  417.  
  418.     move.l    Node,d0            ;get Nodeaddress to d2
  419.     move.l    MyMemoryOffset,a0    ;get address of MyMemoryOffset to a0
  420.     add.l    #22,a0            ;add 22 to get storeaddress
  421.     bsr    binhex            ;convert address to ASCII
  422.  
  423.     add.l    #71,MyMemoryOffset    ;do this for the next loop
  424.     move.l    Node,a1            ;get nodeaddress to a1
  425.     move.l    (a1),Node        ;save address of next node
  426.     move.l    MyMemoryOffset,d0    ;get MyMemoryOffset to d0
  427.     addq.l    #1,d0
  428.     move.l    MyMemoryBlock,d1    ;get MyMemoryBlock to d1
  429.     add.l    MyMemoryLength,d1    ;add MyMemoryLength to d1
  430.     cmp.l    d0,d1            ;see if we have to loop once more
  431.     bne    TheLoop            ;if <> -=> TheLoop
  432.     move.l    MyMemoryBlock,a0    ;get address of MyMemoryBlock to a0
  433.     add.l    MyMemoryLength,a0    ;add length to MyMemoryBlock
  434.     subq.l    #1,a0            ;decrement address by one
  435.     move.b    #0,(a0)            ;set last byte of MyMemoryBlock to NULL
  436.  
  437.     move.l    NodeCount,d3        ;get number of nodes to d3
  438.     move.l    MyMemoryBlock,d2    ;get address of MyMemoryBlock to d2
  439. FinallyPrintIt:
  440.     bsr    TextOutPut        ;print one line
  441.     add.l    #71,d2            ;increment string startaddress by 71
  442.     clr.l    d0            ;clear newSignals
  443.     clr.l    d1            ;clear signalMask
  444.     jsr    SetSignal(a6)        ;get the signalmask of our task
  445.     btst    #12,d0            ;is the CTRL-C Bit set?
  446.     bne    CTRL_C_Break        ;if yes -> CTRL_C_Break
  447.     tst.l    d3            ;get desired flag to CCR
  448.     dbeq    d3,FinallyPrintIt    ;is d3=NULL? (no-=>d3=d3-1-=>FinallyPrintIt
  449.  
  450.     move.l    MyMemoryBlock,a1    ;get address of MyMemoryBlock to a1
  451.     move.l    MyMemoryLength,d0    ;get length of MyMemoryBlock to d0
  452.     jsr    FreeMem(a6)        ;free the allocated RAM
  453.  
  454. PrintLF:
  455.     move.l    #LF,d2            ;get address of LF-string to d2
  456.     bsr.b    TextOutPut        ;and get it out via DOS-Write & stdout
  457.     jsr    Permit(a6)        ;permit taskswitching (I think Dos enables
  458.                     ; this for you, but I do this to be sure
  459.                     ; that taskswitching is now allowed.)
  460.     movem.l    (sp)+,d0-d7/a0-a6    ;restore Registers
  461.     rts
  462.  
  463. *****************************************************************************
  464. *
  465. *    TextOutPut
  466. *            by    Heiko Rath
  467. *                Raiffeisenstr.10a
  468. *                D-6108 Weiterstadt
  469. *                WEST GERMANY (F.R.G.)
  470. *
  471. * PURPOSE:         output a NULL-terminated string via stdout
  472. *
  473. * ROUTINE TYPE:     subroutine
  474. *
  475. * SYNTAX:        bsr    TextOutPut    (stringaddress)(d0)
  476. *
  477. * ENTRY CONDITIONS:    needs DOSlibrary opened and stdout defined
  478. *            also needs DOS-'Write' offset -48 defined.
  479. *
  480. * RETURNS:        none
  481. *
  482. * NOTE:            its better if the string is really NULL-terminated
  483. *
  484. * CHANGED:        nothing
  485. *
  486. * USAGE:        move.l    #Textaddress,d2
  487. *            bsr    TextOutPut
  488. *
  489. *****************************************************************************
  490.  
  491. TextOutPut:
  492.     movem.l    d0-d7/a0-a6,-(sp)    ;save registers
  493.     move.l    d2,a0            ;address to a0
  494.     clr.l    d3            ;count = 0
  495.  
  496. CountLoop:
  497.     tst.b    (a0)+            ;is it NULL ?
  498.     beq.b    PMsg            ;yes: -=> determine length
  499.     addq.l    #1,d3            ;count = count+1
  500.     bra.b    CountLoop        ;test next byte
  501.  
  502. PMsg:
  503.     move.l    stdout,d1        ;get stdout to d1
  504.     move.l    DOSBase,a6        ;move DOSBase to a6
  505.     jsr    Write(a6)        ;write the Text
  506.     movem.l    (sp)+,d0-d7/a0-a6    ;reserve registers
  507.     rts
  508.  
  509. ***********************************************************************
  510. *
  511. *     binhex
  512. *             by Heiko Rath
  513. *
  514. * PURPOSE: Convert a binary value in a register to
  515. *        a hex ASCII string at the destination address
  516. *          
  517. * ROUTINE TYPE: SUBROUTINE
  518. *
  519. * SYNTAX: bsr    binhex    (source(long),destination) (d0.l,a0)
  520. *       bsr    binhexw    (source(word),destination) (d0.w,a0)
  521. *       bsr    binhexb    (source(byte),destination) (d0.b,a0)
  522. *
  523. * ENTRY CONDITIONS: None
  524. *
  525. * RETURNS: ASCII string in destination address
  526. * NOTE:     the destination place must contain 8 bytes for any
  527. *            length (byte, word, longword)
  528. *
  529. * CHANGED: Nothing
  530. *
  531. * USAGE:
  532. *
  533. *     move    #label,d0
  534. *     move.l    address,a0    ;converts the address at label to
  535. *     bsr    binhex        ;string at address
  536. *                
  537. *     move    label,d0
  538. *     move.l    address,a0
  539. *     bsr    binhex        ;conv contents at label
  540. *
  541. *     move    #value,d0
  542. *     move.l    address,a0
  543. *     bsr    binhex        ;convert immediate value
  544. *
  545. ****************************************************************
  546.  
  547. binhex:    movem.l    d0-d2/a0,-(sp)        ;save registers
  548.  
  549.     move.l    #7,d2            ;get number of counts to d2
  550.     clr.l    d1            ;clear work register
  551.  
  552. 001$:    rol.l    #4,d0            ;move high nibble to low order
  553.     move.b    d0,d1            ;get low order byte to d1
  554.     andi.b    #$f,d1            ;isolate low order nibble
  555.     cmp.b    #$0a,d1            ;is it a letter or a digit?
  556.     blt.b    002$            ;if digit -=> 002$
  557.     add.b    #'A'-'0'-$0A,d1        ;offset for letters
  558.  
  559. 002$:    add.b    #'0',d1            ;convert to ASCII
  560.     move.b    d1,(a0)+        ;store it and increment storeaddress
  561.     dbf.b    d2,001$            ;do the converting 8 times
  562.  
  563.     movem.l    (sp)+,d0-d2/a0        ;restore registers
  564.     rts
  565.  
  566. ***********************************************************************
  567. *
  568. *     bindec
  569. *             by Heiko Rath
  570. *
  571. * PURPOSE: Convert a binary value in a register to
  572. *        a dec ASCII string at the destination address
  573. *          
  574. * ROUTINE TYPE: SUBROUTINE
  575. *
  576. * SYNTAX:
  577. *       bsr    bindecw    (source(word),destination) (d0.w,a0)
  578. *       bsr    bindecb    (source(byte),destination) (d0.b,a0)
  579. *
  580. * ENTRY CONDITIONS: None
  581. *
  582. * RETURNS: ASCII string in destination address
  583. * NOTE:     the destination place must contain 5 bytes for any
  584. *            length (byte, word). Don't use longwords!
  585. *
  586. * CHANGED: Nothing
  587. *
  588. * USAGE:
  589. *
  590. *     move    #label,d0
  591. *     move.l    address,a0    ;converts the address at label to
  592. *     bsr    bindec        ;string at address
  593. *                
  594. *     move    label,d0
  595. *     move.l    address,a0
  596. *     bsr    bindec        ;conv contents at label
  597. *
  598. *     move    #value,d0
  599. *     move.l    address,a0
  600. *     bsr    bindec        ;convert immediate value
  601. *
  602. ****************************************************************
  603.  
  604. bindecb:
  605.     movem.l    d0-d2/a0,-(sp)        ;store registers
  606.     move.l    d0,d1
  607.     move.l    a0,a1
  608.     bra.b    ByteToDec
  609.  
  610. bindecw:
  611.     movem.l    d0-d2/a0,-(sp)        ;save registers
  612.     move.l    d0,d1
  613.     move.l    a0,a1
  614.  
  615.     divu    #10000,d1
  616.     bsr.b    StoreOneByte
  617.     divu    #1000,d1
  618.     bsr.b    StoreOneByte
  619. ByteToDec:
  620.     divu    #100,d1
  621.     bsr.b    StoreOneByte
  622.     divu    #10,d1
  623.     bsr.b    StoreOneByte
  624.     bsr.b    StoreOneByte
  625.  
  626. 003$:                    ;003$ is used to clear the
  627.     move.b    (a1)+,d0        ; leading zeros
  628.     cmp.b    #'0',d0
  629.     bne.b    002$
  630.     cmp.b    #' ',(a1)
  631.     beq.b    002$
  632.     move.b    #' ',-(a1)
  633.     add.l    #1,a1
  634.     bra.b    003$
  635. 002$:
  636.     movem.l    (sp)+,d0-d2/a0        ;restore registers
  637.     rts
  638.  
  639. StoreOneByte:
  640.     add.b    #$30,d1
  641.     move.b    d1,(a0)+
  642.     clr.w    d1
  643.     swap    d1
  644.     rts
  645.  
  646. CTRL_C_Break:
  647.     move.l    MyMemoryBlock,a1    ;get address of MyMemoryBlock to a1
  648.     move.l    MyMemoryLength,d0    ;get length of MyMemoryBlock to d0
  649.     jsr    FreeMem(a6)        ;free the allocated RAM
  650.  
  651.     move.b    #1,BreakFlag        ;set our internal break flag
  652.     move.l    #BREAK,d2        ;get address of Break-string to d2
  653.     bsr    TextOutPut        ;and get it out via DOS-Write & stdout
  654.     jsr    Permit(a6)        ;permit taskswitching (I think Dos enables
  655.                     ; this for you, but I do this to be sure
  656.                     ; that taskswitching is now allowed.)
  657.     movem.l    (sp)+,d0-d7/a0-a6    ;restore Registers
  658.     rts
  659.  
  660. ***
  661. *** Variables:
  662. ***
  663.  
  664. DOSBase:    dc.l    0        ;this contains the DOSlibraryaddress
  665. stdout:        dc.l    0        ;this contains stdout
  666. stdin:        dc.l    0        ;this contains stdin
  667. ListHead:
  668.     dc.l    0            ;At runtime this contains the
  669.                     ; address of the listheader
  670. Node:
  671.     dc.l    0            ;At runtime this contains the
  672.                     ; address of the current node
  673. NodeCount:
  674.     dc.l    0            ;At runtime this contains the
  675.                     ; number of nodes in the list
  676. MyMemoryLength:
  677.     dc.l    0            ;At runtime this contains the
  678.                     ; length of the memoryblock
  679. MyMemoryBlock:
  680.     dc.l    0            ;At runtime this contains the
  681.                     ; address of the memoryblock
  682. MyMemoryOffset:
  683.     dc.l    0            ;At runtime this contains the
  684.                     ; address of the memoryblock
  685.                     ; + 71 Bytes per finished node
  686. BreakFlag:
  687.     dc.b    0            ;This is set if we encounter a CTRL-C
  688.     cnop    0,2
  689.  
  690. ***
  691. ***Constants:
  692. ***
  693. liblist:    dc.l    $17a
  694.  
  695. DOSNAME:    cstring    'dos.library'
  696.         cnop    0,2
  697. Err:        dc.b    '*** Out of Memory Error ***',0
  698.         cnop    0,2
  699. NoName:        dc.b    'No Name',0
  700.         cnop    0,2
  701. LF:        dc.b    10,0        ;LF
  702.         cnop    0,2
  703. BREAK:        dc.b    '***BREAK',10,0
  704.         cnop    0,2
  705. HeadLine:    dc.b    $9b,'4;32;40m'
  706.         dc.b    'Name                  Address  Typ Pri OpenC'
  707.         dc.b    ' Vers. Revs.  Neg.  Pos.'
  708.         dc.b    $9b,'0;31;40m',10,0
  709.         cnop    0,2
  710. Text:
  711.     dc.b    $9b,'0;33;40m','Lib-Remover',$9b,'0;31;40m '
  712.     dc.b    $9b,'3;31;40m','V'
  713.     Version
  714.     dc.b    $9b,'0;31;40m'
  715.     dc.b    ' by ',$9b,'0;32;40m','Heiko Rath',$9b,'0;31;40m',' - '
  716.     dc.b    $9b,'4;31;40m',169,'1988 by ',$9b,'1;31;40m'
  717.     dc.b    'The Software Brewery',$9b,'0;31;40m',10
  718.     dc.b    'Raiffeisenstr.10a,  D-6108 Weiterstadt,  '
  719.     dc.b    'WEST GERMANY  (F.R.G.)',10,0
  720.  
  721. Successfull:
  722.     dc.b    10,'Succeeded in removing the library.',10,0
  723.     cnop    0,2
  724. NotAbleToClose:
  725.     dc.b    10,$9b,'0;33;40m','Attention:',$9b,'0;31;40m'
  726.     dc.b    ' This library can not be closed, cause OpenCnt > 0.',10,0
  727.     cnop    0,2
  728. FailedToRemove:
  729.     dc.b    10,$9b,'0;33;40m','Attention:',$9b,'0;31;40m'
  730.     dc.b    ' Failed to remove the library.',10,0
  731.     cnop    0,2
  732. NotFound:
  733.     dc.b    10,$9b,'0;33;40m','Attention:',$9b,'0;31;40m'
  734.     dc.b    ' Library not found.',10,0
  735.     cnop    0,2
  736. HelpText:
  737.     dc.b    10,'Use ',$9b,'0;33;40m','Remlib',$9b,'0;31;40m'
  738.     dc.b    ' without argument to display all libraries.',10
  739.     dc.b    'Use ',$9b,'0;33;40m','Remlib',$9b,'0;31;40m'
  740.     dc.b    ' "name.library" to remove a library.',10
  741.     dc.b    'Note: It''s only possible to remove libraries with',10
  742.     dc.b    '      an opencount of 0.',10,0
  743. SHAR_EOF
  744. cat << \SHAR_EOF > remlib.uu
  745.  
  746. begin 644 remlib
  747. M```#\P`````````!``````````````''```#Z0```<<L#R1(4T!",@``+'@`%
  748. M!")\```#^'``3J[]V$J`9P``RB/````#SBQ`3J[_Q"/````#TB0\```$C&$`!
  749. M`LX2&F<``(8,`0`@9_0,`0`_9P``G@P!`")F&%**(DH2&6<``%`,`0`B9P)@1
  750. M\E.)$KP``%.*+'@`!"!.T?H#?")*3J[^[$J`9RHB0#`I`"!*0&8L3J[^;DJ`O
  751. M9@PD/```!=9A``)J8#8D/```!5YA``)>8"HD/```!A1A``)28!XD/```!81A5
  752. M``)&8!(D/```!#1A``(Z(#H#(F$``"(L>``$(GH"\"QX``1.KOYB+D9.=20\"
  753. M```&1F$``A1@X$CG__XL>``$3J[_?"!.T<`CR````]HB4"/)```#WEB(L<EG5
  754. M``':<@$B44J19P12@6#V(\$```/B<$?`P5*`(\````/F(CP``0`!3J[_.B/`'
  755. M```#ZB/````#[DJ`9@``$"0\```$!&$``:A@``&2($`B.@)\$/P`(%?)__H@%
  756. M>@)X(GH"9$/I``HB47(`=`"T&6<$4H%@^`P!`!1O`G(4(GH"1D/I``HB44J!8
  757. M9@``"B)\```$('('4X$1L1``$`!1R?_X('H",A%\`"0`%1%\`"0`(Q%\``H`Q
  758. M11%\````1B)Z`@90B7``$!$@>@(,0>@`'V$``6@B>@'P0^D`"7``$!$@>@'T"
  759. M0>@`(V$``5`B>@'80^D`('``,!$@>@'<0>@`)V$``4(B>@'`0^D`%'``,!$@)
  760. M>@'$0>@`+6$``2HB>@&H0^D`%G``,!$@>@&L0>@`,V$``1(B>@&00^D`$'``)
  761. M,!$@>@&40>@`.6$``/HB>@%X0^D`$G``,!$@>@%\0>@`/V$``.(@.@%@('H!)
  762. M;$'H`!9A``"@!KD```!'```#[B)Z`48CT0```]X@.@%,4H`B.@%"TKH!.K*`L
  763. M9@#^PB!Z`331^@$L4X@0O```)CH!'B0Z`2)A```\!H(```!'0H!"@4ZN_LX(5
  764. M```,9@``Q$J#5\O_XB)Z`/X@.@#V3J[_+B0\```$*&$*3J[_=DS??_].=4CG<
  765. M__X@0D*#2AAG!%*#8/@B.@"X+'H`L$ZN_]!,WW__3G5(Y^"`=`="@>F8$@`"A
  766. M`0`/#`$`"FT"7@$&`0`P$,%1RO_H3-\!!TYU2.?@@"(`(DA@%$CGX(`B`")(?
  767. M@OPG$&$P@OP#Z&$J@OP`9&$D@OP`"F$>81P0&0P``#!F#@P1`"!G"!,\`"!2K
  768. MB6#J3-\!!TYU!@$`,!#!0D%(04YU(GH`0B`Z`#I.KO\N$_P``0```_(D/```@
  769. M!"IA`/]&3J[_=DS??_].=0``````````````````````````````````````Q
  770. M```````````````!>F1O<RYL:6)R87)Y`"HJ*B!/=70@;V8@365M;W)Y($5R?
  771. M<F]R("HJ*@!.;R!.86UE``H`*BHJ0E)%04L*`)LT.S,R.S0P;4YA;64@("`@"
  772. M("`@("`@("`@("`@("!!9&1R97-S("!4>7`@4')I($]P96Y#(%9E<G,N(%)E(
  773. M=G,N("!.96<N("!0;W,NFS`[,S$[-#!M"@";,#LS,SLT,&U,:6(M4F5M;W9EI
  774. M<ILP.S,Q.S0P;2";,SLS,3LT,&U6,2XQ,9LP.S,Q.S0P;2!B>2";,#LS,CLT#
  775. M,&U(96EK;R!2871HFS`[,S$[-#!M("T@FS0[,S$[-#!MJ3$Y.#@@8GD@FS$[^
  776. M,S$[-#!M5&AE(%-O9G1W87)E($)R97=E<GF;,#LS,3LT,&T*4F%I9F9E:7-E*
  777. M;G-T<BXQ,&$L("!$+38Q,#@@5V5I=&5R<W1A9'0L("!715-4($=%4DU!3ED@5
  778. M("A&+E(N1RXI"@`*4W5C8V5E9&5D(&EN(')E;6]V:6YG('1H92!L:6)R87)YG
  779. M+@H```J;,#LS,SLT,&U!='1E;G1I;VXZFS`[,S$[-#!M(%1H:7,@;&EB<F%RT
  780. M>2!C86X@;F]T(&)E(&-L;W-E9"P@8V%U<V4@3W!E;D-N="`^(#`N"@`*FS`[G
  781. M,S,[-#!M071T96YT:6]N.ILP.S,Q.S0P;2!&86EL960@=&\@<F5M;W9E('1HJ
  782. M92!L:6)R87)Y+@H```J;,#LS,SLT,&U!='1E;G1I;VXZFS`[,S$[-#!M($QIO
  783. M8G)A<GD@;F]T(&9O=6YD+@H`"E5S92";,#LS,SLT,&U296UL:6*;,#LS,3LT(
  784. M,&T@=VET:&]U="!A<F=U;65N="!T;R!D:7-P;&%Y(&%L;"!L:6)R87)I97,N1
  785. M"E5S92";,#LS,SLT,&U296UL:6*;,#LS,3LT,&T@(FYA;64N;&EB<F%R>2(@H
  786. M=&\@<F5M;W9E(&$@;&EB<F%R>2X*3F]T93H@270G<R!O;FQY('!O<W-I8FQE)
  787. M('1O(')E;6]V92!L:6)R87)I97,@=VET:`H@("`@("!A;B!O<&5N8V]U;G0@>
  788. M;V8@,"X*`````^P````7`````````!`````B````+@```#0```"8````I```S
  789. M`+````"\````R````.X```$*```!$@```2P```$X```!2````4X```%:```!:
  790. =J````I(```*<```"^````[8```.\`````````_(XY
  791. ``
  792. end
  793. size 1964
  794. SHAR_EOF
  795. #    End of shell archive
  796. exit 0
  797. -- 
  798. Bob Page, U of Lowell CS Dept.  page@swan.ulowell.edu  ulowell!page
  799. Have five nice days.
  800.